Mac Forum / Applications / Excel / December 2008

Unfortunately, I don't know of anything that will change XL's native
hyperlink behavior. Certainly in versions other than XL08, one could
come up with event macro-driven solutions.

For example, one could put this in the ThisWorkbook code module:

   Private Sub Workbook_Open()
       gbSwitchedSheets = ActiveSheet.Name <> "Publications Review"
   End Sub

Put this in the 'Publications Review' worksheet code module:
   
   Private Sub Worksheet_Activate()
       Application.OnTime _
           EarliestTIme:=Now() + TimeSerial(0, 0, 1), _
           Procedure:="DisableAutoScroll"
   End Sub
   
   Private Sub Worksheet_Deactivate()
       gbSwitchedSheets = True
   End Sub

   Private Sub Worksheet_SelectionChange(ByVal Target As Excel.Range)
        If gbSwitchedSheets Then
           ActiveWindow.ScrollRow = ActiveCell.Row
           gbSwitchedSheets = False
       End If
   End Sub

And put this in a regular code module:

   Public gbSwitchedSheets As Boolean

   Public Sub DisableAutoScroll()
       gbSwitchedSheets = False
   End Sub

The work is done in the Worksheet_SelectionChange() routine. Everything
else is to prevent scrolling when the sheet is entered via, say,
clicking on the worksheet tab.